# Declara los personajes utilizados en este juego.
define s = Character(_("Silvana"), color="#c8ffc8")
define m = Character(_("Yo"), color="#c8c8ff")

# Esta es una variable que es Verdadera si comparas un NV con un libro, y Falsa
# si haces lo contrario.
default libro = False

# El juego comienza aca.
label start:

    # Empieza reproduciendo un tema musical.
    play music "illurock.opus"

    scene bg lecturehall
    with fade

    "Es solo cuando oigo los sonidos de pisadas y los utiles guardandose, que me doy cuenta que la clase termino."

    "Las clases de la profe Ailin suelen ser interesantes, pero hoy no pude concentrarme para nada."

    "Un monton de cosas me pasan por la cabeza... inquietudes que culminaran con una pregunta."

    "Es una pregunta que he querido hacerle a alguien."

    scene bg uni
    with fade

    "Cuando salimos del colegio, la veo alli."

    show sylvie green normal
    with dissolve

    "Conozco a Silvana desde que eramos ninos. Tiene un gran corazon y siempre ha sido buena amiga conmigo."

    "Pero recientemente,... quiero algo mas."

    "Mas que solo hablar, mas que solo caminar a casa junt@s cuando termina la clase."

    menu:

        "Tan pronto como me observa, decido..."

        "Preguntarle ahora mismo.":

            jump deuna

        "Preguntarle mas tarde.":

            jump despues

label deuna:

    show sylvie green smile

    s "¡Como va! ¿Que tal estuvo la clase?"

    m "Estuvo buena..."

    "No puedo admitir que me entro por un oido y me salio por el otro."

    m "¿Te vas a tu casa? ¿Queres que volvamos juntos?"

    s "¡Dale!"

    scene bg meadow
    with fade

    "A poco de caminar, alcanzamos los prados justo al lado del vecindario donde vivimos."

    "Es una vista muy linda a la que me fui acostumbrando. El otono es especialmente hermoso por estos lares."

    "Cuando eramos chic@s, jugabamos mucho en estos campitos, estan llenos de recuerdos."

    m "Che... Umm..."

    show sylvie green smile
    with dissolve

    "Gira hacia mi y sonrie. Parece tan a gusto que siento que mis nervios desaparecen."

    "Le voy a preguntar...!"

    m "Ummm... ¿Serias..."

    m "¿Serias mi artista para una novela visual?"

    show sylvie green surprised

    "Silencio."

    "Parecia tan shockeada que comence a temer lo peor. Pero entonces..."

    show sylvie green smile

    menu:

        s "Seguro, pero ¿que es una \"novela visual?\""

        "Es un videojuego.":
            jump juego

        "Es un libro interactivo.":
            jump libro

label juego:

    m "Es como un videojuego que jugas en la computadora o en el celular."

    m "Las novelas visuales cuentan una historia con imagenes y musica."

    m "A veces tenes que decidir cosas que afectan el devenir de la historia."

    m "Asi que es como los libros de \"elige tu propia aventura\"?"

    m "Exacto! Tengo muchas ideas que podrian funcionar."

    m "Y pense que tal vez podrias ayudarme... ya que se que te gusta dibujar."

    m "Seria dificil para mi hacer una novela visual si dependiera solo de mi."

    show sylvie green normal

    s "Bueno, claro! puedo probar. Solo espero no ser un desastre."

    m "Vos sabes que nunca me decepcionarias, Silvi."

    jump casamiento

label libro:

    $ libro = True

    m "Es como un libro interactivo que lees en una computadora o una consola."

    show sylvie green surprised

    s "¿Interactivo?"

    m "Podes hacer elecciones que te lleven por distintos eventos y distintos finales de la historia."

    s "Y de donde viene lo de \"visual\" en todo esto?"

    m "Las novelas visuales tienen imagenes e incluso musica, efectos de sonido, y a veces hasta doblaje de voces, que se reproducen a la vez que aparece el texto."

    show sylvie green smile

    s "Ya veo! Parece bastante divertido. Hace mucho yo hice {i}webcomics{/i}, asi que tengo muchas ideas para hacer historias."

    m "Buenisimo! Asi que te interesaria trabajar conmigo como artista?"

    s "Me encantaria!"

    jump casamiento

label casamiento:

    scene black
    with dissolve

    "Y fue asi como nos volvimos una dupla creadora de novelas visuales."

    scene bg club
    with dissolve

    "Con el pasar de los anos, hicimos montones de juegos y nos divertimos mucho haciendolos."

    if libro:

        "Nuestro primer juego se basa en las ideas de Silvana, pero luego se me ocurrieron mis propias historias tambien."

    "Nos turnamos creando nuevas historias y personajes ¡y nos apoyamos mutuamente para hacer los mejores juegos!"

    "Y un dia..."

    show sylvie blue normal
    with dissolve

    s "Ey..."

    m "¿Si?"

    show sylvie blue giggle

    s "¿Te casarias conmigo?"

    m "¿Que? ¿De donde sale esto?"

    show sylvie blue surprised

    s "Dale, ¿cuanto hace que salimos?"

    m "Un tiempo ya..."

    show sylvie blue smile

    s "Estos ultimos anos hicimos novelas visuales junt@s, pasamos tiempo junt@s, nos ayudamos entre nosotr@s..."

    s "Hemos llegado a conocernos y cuidar de nosotr@s mejor que nadie. Creo que pensas lo mismo, verdad?"

    m "Silvana..."

    show sylvie blue giggle

    s "Pero yo se que sos indecis@. Si no hago nada, quien sabe cuando lo propondrias?"

    show sylvie blue normal

    s "Asi que te casarias conmigo?"

    m "Por supuesto que si! Ya estaba pensando en proponertelo, para ser honest@!"

    s "Ya se, ya se."

    m "Supongo... que estaba muy preocupad@ por el timing. Queria preguntar la pregunta precisa en el momento correcto."

    show sylvie blue giggle

    s "Te preocupas demasiado. Si tan solo esto fuese una novela visual, podria elegir una opcion que aparece en un menu, ¡seria mas valiente!"

    scene black
    with dissolve

    "Nos casamos poco despues."

    "Nuestro duo de novelas visuales continua despues de habernos casado... y yo di lo mejor de mi para ser mas decidid@."

    "Junt@s, vivimos felices y comimos perdices veganas en un mundo de anime barato."

    "{b}¡Final Feliz!{/b}."

    return

label despues:

    "No puedo superar los nervios de preguntarle ahora. Tragando saliva, decido preguntarle mas tarde."

    scene black
    with dissolve

    "Pero soy una persona indecisa."

    "No pude preguntarle ese dia, y al final nunca pude preguntarle."

    "Supongo que jamas sabre la respuesta a mi pregunta..."

    "{b}¡Final para pegarse un tiro!{/b}."

    return